mirror of
https://github.com/justinian/jsix.git
synced 2025-12-10 00:14:32 -08:00
cd037aca15
The main point of this change is to allow "global" capabilities defined on the base object type. The example here is the clone capability on all objects, which governs the ability to clone a handle. Related changes in this commit: - Renamed `kobject` to `object` as far as the syscall interface is concerned. `kobject` is the cname, but j6_cap_kobject_clone feels clunky. - The above change made me realize that the "object <type>" syntax for specifying object references was also clunky, so now it's "ref <type>" - Having to add `.object` on everywhere to access objects in interface.exposes or object.super was cumbersome, so those properties now return object types directly, instead of ObjectRef. - syscall_verify.cpp.cog now generates code to check capabilities on handles if they're specified in the definition, even when not passing an object to the implementation function.
48 lines
1.0 KiB
Plaintext
48 lines
1.0 KiB
Plaintext
start: import_statement* (object|interface)+
|
|
|
|
import_statement: "import" PATH
|
|
|
|
object: description? "object" name options? super? "{" uid cname? capabilities? method* "}"
|
|
|
|
interface: description? "interface" name options? "{" uid interface_param* "}"
|
|
|
|
?interface_param: expose | function
|
|
|
|
expose: "expose" type
|
|
|
|
uid: "uid" UID
|
|
|
|
cname: "cname" IDENTIFIER
|
|
|
|
capabilities: "capabilities" "[" IDENTIFIER+ "]"
|
|
|
|
super: ":" name
|
|
|
|
function: description? "function" name options? ("{" param* "}")?
|
|
|
|
method: description? "method" name options? ("{" param* "}")?
|
|
|
|
param: "param" name type options? description?
|
|
|
|
?type: PRIMITIVE | object_name
|
|
|
|
object_name: "ref" name
|
|
|
|
id: NUMBER
|
|
name: IDENTIFIER
|
|
options: "[" ( OPTION | IDENTIFIER )+ "]"
|
|
description: COMMENT+
|
|
|
|
PRIMITIVE: INT_TYPE | "size" | "string" | "buffer" | "address"
|
|
INT_TYPE: /u?int(8|16|32|64)?/
|
|
NUMBER: /(0x)?[0-9a-fA-F]+/
|
|
UID: /[0-9a-fA-F]{16}/
|
|
OPTION.2: IDENTIFIER ":" IDENTIFIER
|
|
COMMENT: /#.*/
|
|
PATH: /"[^"]*"/
|
|
|
|
%import common.LETTER
|
|
%import common.CNAME -> IDENTIFIER
|
|
%import common.WS
|
|
%ignore WS
|