[project] Clean up src/ tree

A long overdue cleanup of the src/ tree.

- Moved src/drivers to src/user because it contains more than drivers
- Removed src/drivers/ahci because it's unused - will restore it when I
  make a real AHCI driver
- Removed unused src/tools
- Moved kernel.ld (the only used file under src/arch) to src/kernel for
  now, if/when there's a multi-platform effort that should be figured
  out as part of it
- Removed the rest of the unused src/arch
- Renamed 'fb' to 'drv.uefi_fb' and 'nulldrv' to 'testapp'

src/kernel/kernel.ld

@@ -0,0 +1,53 @@
+ENTRY(_kernel_start)
+SECTIONS
+{
+	. = 0xFFFF800000000000;
+
+	.header : {
+		__header_start = .;
+		KEEP(*(.header))
+		__header_end = .;
+	}
+
+	.text ALIGN(4096) : {
+		*(.text*)
+		KEEP(*(.isrs))
+	}
+
+	.data ALIGN(4096) : {
+		 *(.data*)
+		 *(.rodata*)
+	}
+
+	.ctors : ALIGN(8) {
+		 __ctors = .;
+		 KEEP(*(.ctors))
+		 KEEP(*(.init_array))
+		 __ctors_end = .;
+	 }
+
+	.bss ALIGN(4096) : {
+		__bss_start = .;
+		*(.bss*)
+		__bss_end = .;
+	}
+
+	.note : {
+		*(.note.*)
+	}
+
+	.eh_frame : {
+		__eh_frame_start = .;
+		KEEP(*(.eh_frame))
+		__eh_frame_end = .;
+	}
+
+	.eh_frame_hdr : {
+		KEEP(*(.eh_frame_hdr))
+	}
+
+	__eh_frame_hdr_start = SIZEOF(.eh_frame_hdr) > 0 ? ADDR(.eh_frame_hdr) : 0;
+	__eh_frame_hdr_end = SIZEOF(.eh_frame_hdr) > 0 ? . : 0;
+
+	kernel_end = ALIGN(4096);
+}